home *** CD-ROM | disk | FTP | other *** search
/ The Arsenal Files 8 / The Arsenal Files Collection #8 (Arsenal Computer) (1996).ISO / g_quake / dmmde321.zip / SHALRATH.QC < prev    next >
Text File  |  1996-08-16  |  9KB  |  275 lines
  1. /*
  2. ==============================================================================
  3.  
  4. SHAL-RATH
  5.  
  6. ==============================================================================
  7. */
  8. $cd /raid/quake/id1/models/shalrath
  9. $origin 0 0 24
  10. $base base
  11. $skin skin
  12. $scale 0.7
  13.  
  14. $frame attack1 attack2 attack3 attack4 attack5 attack6 attack7 attack8
  15. $frame attack9 attack10 attack11
  16.  
  17. $frame pain1 pain2 pain3 pain4 pain5 
  18.  
  19. $frame death1 death2 death3 death4 death5 death6 death7
  20.  
  21. $frame    walk1 walk2 walk3 walk4 walk5 walk6 walk7 walk8 walk9 walk10
  22. $frame    walk11 walk12
  23.  
  24. void() shalrath_respawn;
  25. void() shalrath_pain;
  26. void() ShalMissile;
  27. void() shal_stand     =[      $walk1,       shal_stand    ] {ai_stand();};
  28.  
  29. void() shal_walk1     =[      $walk2,       shal_walk2    ] {
  30. if (random() < 0.2)
  31.     sound (self, CHAN_VOICE, "shalrath/idle.wav", 1, ATTN_IDLE);
  32. ai_walk(6);};
  33. void() shal_walk2     =[      $walk3,       shal_walk3    ] {ai_walk(4);};
  34. void() shal_walk3     =[      $walk4,       shal_walk4    ] {ai_walk(0);};
  35. void() shal_walk4     =[      $walk5,       shal_walk5    ] {ai_walk(0);};
  36. void() shal_walk5     =[      $walk6,       shal_walk6    ] {ai_walk(0);};
  37. void() shal_walk6     =[      $walk7,       shal_walk7    ] {ai_walk(0);};
  38. void() shal_walk7     =[      $walk8,       shal_walk8    ] {ai_walk(5);};
  39. void() shal_walk8     =[      $walk9,       shal_walk9    ] {ai_walk(6);};
  40. void() shal_walk9     =[      $walk10,       shal_walk10    ] {ai_walk(5);};
  41. void() shal_walk10    =[      $walk11,       shal_walk11    ] {ai_walk(0);};
  42. void() shal_walk11    =[      $walk12,       shal_walk12    ] {ai_walk(4);};
  43. void() shal_walk12    =[      $walk1,       shal_walk1    ] {ai_walk(5);};
  44.  
  45. void() shal_run1     =[      $walk2,       shal_run2    ] {
  46. if (random() < 0.2)
  47.     sound (self, CHAN_VOICE, "shalrath/idle.wav", 1, ATTN_IDLE);
  48. ai_run(6);};
  49. void() shal_run2     =[      $walk3,       shal_run3    ] {ai_run(4);};
  50. void() shal_run3     =[      $walk4,       shal_run4    ] {ai_run(0);};
  51. void() shal_run4     =[      $walk5,       shal_run5    ] {ai_run(0);};
  52. void() shal_run5     =[      $walk6,       shal_run6    ] {ai_run(0);};
  53. void() shal_run6     =[      $walk7,       shal_run7    ] {ai_run(0);};
  54. void() shal_run7     =[      $walk8,       shal_run8    ] {ai_run(5);};
  55. void() shal_run8     =[      $walk9,       shal_run9    ] {ai_run(6);};
  56. void() shal_run9     =[      $walk10,       shal_run10    ] {ai_run(5);};
  57. void() shal_run10    =[      $walk11,       shal_run11    ] {ai_run(0);};
  58. void() shal_run11    =[      $walk12,       shal_run12    ] {ai_run(4);};
  59. void() shal_run12    =[      $walk1,       shal_run1    ] {ai_run(5);};
  60.  
  61. void() shal_attack1     =[      $attack1,       shal_attack2    ] {
  62. sound (self, CHAN_VOICE, "shalrath/attack.wav", 1, ATTN_NORM);
  63. ai_face();
  64. };
  65. void() shal_attack2     =[      $attack2,       shal_attack3    ] {ai_face();};
  66. void() shal_attack3     =[      $attack3,       shal_attack4    ] {ai_face();};
  67. void() shal_attack4     =[      $attack4,       shal_attack5    ] {ai_face();};
  68. void() shal_attack5     =[      $attack5,       shal_attack6    ] {ai_face();};
  69. void() shal_attack6     =[      $attack6,       shal_attack7    ] {ai_face();};
  70. void() shal_attack7     =[      $attack7,       shal_attack8    ] {ai_face();};
  71. void() shal_attack8     =[      $attack8,       shal_attack9    ] {ai_face();};
  72. void() shal_attack9     =[      $attack9,       shal_attack10   ] {ShalMissile();};
  73. void() shal_attack10    =[      $attack10,      shal_attack11   ] {ai_face();};
  74. void() shal_attack11    =[      $attack11,      shal_run1   ] {};
  75.  
  76. void() shal_pain1       =[      $pain1, shal_pain2      ] {};
  77. void() shal_pain2       =[      $pain2, shal_pain3      ] {};
  78. void() shal_pain3       =[      $pain3, shal_pain4      ] {};
  79. void() shal_pain4       =[      $pain4, shal_pain5      ] {};
  80. void() shal_pain5       =[      $pain5, shal_run1      ] {};
  81.  
  82. void() shal_death1      =[      $death1,        shal_death2     ] {};
  83. void() shal_death2      =[      $death2,        shal_death3     ] {};
  84. void() shal_death3      =[      $death3,        shal_death4     ] {};
  85. void() shal_death4      =[      $death4,        shal_death5     ] {};
  86. void() shal_death5      =[      $death5,        shal_death6     ] {};
  87. void() shal_death6      =[      $death6,        shal_death7     ] {};
  88. void() shal_death7      =[      $death7,        shal_death7    ] {
  89.         if (deathmatch > 4)
  90.         {
  91.                 self.think = shalrath_respawn;
  92.                 self.nextthink = time + 30;
  93.         }
  94. };
  95.  
  96. void() shalrath_pain =
  97. {
  98.     if (self.pain_finished > time)
  99.         return;
  100.  
  101.     sound (self, CHAN_VOICE, "shalrath/pain.wav", 1, ATTN_NORM);
  102.     shal_pain1();
  103.     self.pain_finished = time + 3;
  104. };
  105.  
  106. void() shalrath_die =
  107. {
  108. // check for gib
  109.     if (self.health < -90)
  110.     {
  111.         sound (self, CHAN_VOICE, "player/udeath.wav", 1, ATTN_NORM);
  112.         ThrowHead ("progs/h_shal.mdl", self.health);
  113.         ThrowGib ("progs/gib1.mdl", self.health);
  114.         ThrowGib ("progs/gib2.mdl", self.health);
  115.         ThrowGib ("progs/gib3.mdl", self.health);
  116.  
  117.                 if ((deathmatch == 6) || (deathmatch == 7))
  118.                 {
  119.                         self.think = shalrath_respawn;
  120.                         self.nextthink = time + 30;
  121.                 }
  122.         return;
  123.     }
  124.  
  125.     sound (self, CHAN_VOICE, "shalrath/death.wav", 1, ATTN_NORM);
  126.     shal_death1();
  127.     self.solid = SOLID_NOT;
  128.     // insert death sounds here
  129. };
  130.  
  131. /*
  132. ================
  133. ShalMissile
  134. ================
  135. */
  136. void() ShalMissileTouch;
  137. void() ShalHome;
  138. void() ShalMissile =
  139. {
  140.     local    entity     missile;
  141.     local    vector    dir;
  142.     local    float    dist, flytime;
  143.  
  144.     dir = normalize((self.enemy.origin + '0 0 10') - self.origin);
  145.     dist = vlen (self.enemy.origin - self.origin);
  146.     flytime = dist * 0.002;
  147.     if (flytime < 0.1)
  148.         flytime = 0.1;
  149.  
  150.     self.effects = self.effects | EF_MUZZLEFLASH;
  151.     sound (self, CHAN_WEAPON, "shalrath/attack2.wav", 1, ATTN_NORM);
  152.  
  153.     missile = spawn ();
  154.     missile.owner = self;
  155.  
  156.     missile.solid = SOLID_BBOX;
  157.     missile.movetype = MOVETYPE_FLYMISSILE;
  158.     setmodel (missile, "progs/v_spike.mdl");
  159.  
  160.     setsize (missile, '0 0 0', '0 0 0');        
  161.  
  162.     missile.origin = self.origin + '0 0 10';
  163.     missile.velocity = dir * 400;
  164.     missile.avelocity = '300 300 300';
  165.     missile.nextthink = flytime + time;
  166.     missile.think = ShalHome;
  167.     missile.enemy = self.enemy;
  168.     missile.touch = ShalMissileTouch;
  169. };
  170.  
  171. void() ShalHome =
  172. {
  173.     local vector    dir, vtemp;
  174.     vtemp = self.enemy.origin + '0 0 10';
  175.     if (self.enemy.health < 1)
  176.     {
  177.         remove(self);
  178.         return;
  179.     }
  180.     dir = normalize(vtemp - self.origin);
  181.     if (skill == 3)
  182.         self.velocity = dir * 350;
  183.     else
  184.         self.velocity = dir * 250;
  185.     self.nextthink = time + 0.2;
  186.     self.think = ShalHome;    
  187. };
  188.  
  189. void() ShalMissileTouch =
  190. {
  191.     if (other == self.owner)
  192.         return;        // don't explode on owner
  193.  
  194.     if (other.classname == "monster_zombie")
  195.         T_Damage (other, self, self, 110);    
  196.     T_RadiusDamage (self, self.owner, 40, world);
  197.     sound (self, CHAN_WEAPON, "weapons/r_exp3.wav", 1, ATTN_NORM);
  198.  
  199.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  200.     WriteByte (MSG_BROADCAST, TE_EXPLOSION);
  201.     WriteCoord (MSG_BROADCAST, self.origin_x);
  202.     WriteCoord (MSG_BROADCAST, self.origin_y);
  203.     WriteCoord (MSG_BROADCAST, self.origin_z);
  204.  
  205.     self.velocity = '0 0 0';
  206.     self.touch = SUB_Null;
  207.     setmodel (self, "progs/s_explod.spr");
  208.     self.solid = SOLID_NOT;
  209.     s_explode1 ();
  210. };
  211.  
  212. //=================================================================
  213.  
  214. /*QUAKED monster_shalrath (1 0 0) (-32 -32 -24) (32 32 48) Ambush
  215. */
  216. void() monster_shalrath =
  217. {
  218.         if ((deathmatch) && (deathmatch < 4))
  219.     {
  220.         remove(self);
  221.         return;
  222.     }
  223.     precache_model2 ("progs/shalrath.mdl");
  224.     precache_model2 ("progs/h_shal.mdl");
  225.     precache_model2 ("progs/v_spike.mdl");
  226.     
  227.     precache_sound2 ("shalrath/attack.wav");
  228.     precache_sound2 ("shalrath/attack2.wav");
  229.     precache_sound2 ("shalrath/death.wav");
  230.     precache_sound2 ("shalrath/idle.wav");
  231.     precache_sound2 ("shalrath/pain.wav");
  232.     precache_sound2 ("shalrath/sight.wav");
  233.         
  234.         self.mdl = self.model;
  235.     self.solid = SOLID_SLIDEBOX;
  236.     self.movetype = MOVETYPE_STEP;
  237.         self.oldorigin = self.origin;
  238.     
  239.     setmodel (self, "progs/shalrath.mdl");
  240.     setsize (self, VEC_HULL2_MIN, VEC_HULL2_MAX);
  241.     self.health = 400;
  242.  
  243.     self.th_stand = shal_stand;
  244.     self.th_walk = shal_walk1;
  245.     self.th_run = shal_run1;
  246.     self.th_die = shalrath_die;
  247.     self.th_pain = shalrath_pain;
  248.     self.th_missile = shal_attack1;
  249.  
  250.     self.think = walkmonster_start;
  251.     self.nextthink = time + 0.1 + random ()*0.1;    
  252.  
  253. };
  254.  
  255. void() shalrath_respawn =
  256. {
  257.         spawn_tfog(self.origin);
  258.         spawn_tfog(self.oldorigin);
  259.         spawn_tdeath(self.oldorigin, self);
  260.     setmodel (self, "progs/shalrath.mdl");
  261.         self.movetype = MOVETYPE_STEP;
  262.         self.solid = SOLID_SLIDEBOX;
  263.     self.health = 400;
  264.     setsize (self, VEC_HULL2_MIN, VEC_HULL2_MAX);
  265.         setorigin (self, self.oldorigin);
  266.     self.th_stand = shal_stand;
  267.     self.th_walk = shal_walk1;
  268.     self.th_run = shal_run1;
  269.     self.th_die = shalrath_die;
  270.     self.th_pain = shalrath_pain;
  271.     self.th_missile = shal_attack1;
  272.         walkmonster_start();
  273. };
  274.  
  275.